[Home]AlexChurchill/DateGenerator

ec2-35-170-81-210.compute-1.amazonaws.com | ToothyWiki | AlexChurchill | RecentChanges | Login | Advent calendar | Webcomic

BNF: AlexChurchill/DateGenerator

A generator for stereotypical dates towards the start of a romantic relationship.

Expand the vocab a bit and you'll put Mills & Boon out of business! ;) - MoonShadow
I'd been idly wondering about writing it anyway, and then someone on a forum said they were looking for ideas for a DatingSim they were writing, so... ^^ --AC



bnf ::= init setting activity conversation conclusion
option ::= spaces = 0
space ::= " "
nothing ::= ""

init ::= <theseason::=chooseseason> <thetime::=choosetime> <<theplace::=deliberateplace>> init##theplace chooseorder
chooseseason ::= spring | summer | autumn | winter
choosetime ::= afternoon | evening

setting ::= "On a " weather##theseason##thetime space theseason space thetime ", the two of them " metaccidentallyoronpurpose ". " | HeorShe1? " had arranged to meet " himorher2 space meetpreposition space display##theplace ". It was a " weather##theseason##thetime space theseason space thetime maybewhentheymet ". "

metaccidentallyoronpurpose ::= metonpurpose | metonpurpose | metaccidentally
metonpurpose ::= "went " goprefix space display##theplace | "met up as arranged " meetpreposition space display##theplace
metaccidentally ::= "met by chance " accidentalplace{theplace} | "bumped into one another " accidentalplace{theplace}

weather_spring_afternoon ::= warm | bright
weather_spring_evening ::= warm
weather_summer_afternoon ::= hot
weather_summer_evening ::= warm | cool
weather_autumn_afternoon ::= crisp
weather_autumn_evening ::= cool
weather_winter_afternoon ::= crisp
weather_winter_evening ::= crisp

deliberateplace ::= childhoodplace##thetime | wateryplace | natureplace##thetime | adultdateplace##thetime
accidentalplace ::= riverwalking | rainsheltering | walkinghome

natureplace_afternoon ::= riverwalk | forestwalk | picnic
natureplace_evening ::= riverwalk | watchsunset
childhoodplace_afternoon ::= fairground | themepark | playground
childhoodplace_evening ::= fairground | watchfireworks | playground
adultdateplace_afternoon ::= cinema | cafe
adultdateplace_evening ::= cinema | restaurant
wateryplace ::= beach | pool

init_riverwalk ::= <meetpreposition::=to> <goprefix::=for>
init_forestwalk ::= <meetpreposition::=to> <goprefix::=for>
init_picnic ::= <meetpreposition::=for> <goprefix::=for>
init_watchsunset ::= <meetpreposition::=to> <goprefix::=to>
init_fairground ::= <meetpreposition::=at> <goprefix::=to>
init_playground ::= <meetpreposition::=at> <goprefix::=to>
init_themepark ::= <meetpreposition::=togoto> <goprefix::=to>
init_watchfireworks ::= <meetpreposition::=to> <goprefix::=to>
init_cinema ::= <meetpreposition::=at> <goprefix::=to>
init_cafe ::= <meetpreposition::=at> <goprefix::=to>
init_restaurant ::= <meetpreposition::=at> <goprefix::=to>
init_beach ::= <meetpreposition::=at> <goprefix::=to>
init_pool ::= <meetpreposition::=at> <goprefix::=to>

display_riverwalk ::= "walk beside the river"
display_forestwalk ::= "walk in the forest"
display_picnic ::= "a picnic"
display_watchsunset ::= "watch the sunset from a hill"
display_fairground ::= "a fairground"
display_playground ::= "a playground"
display_themepark ::= "a theme park"
display_watchfireworks ::= "watch the fireworks"
display_cinema ::= "the cinema"
display_cafe ::= "a cafe"
display_restaurant ::= "a restaurant"
display_beach ::= "the beach"
display_pool ::= "a swimming pool"

togoto ::= "to go to"
fora ::= "for a"
maybewhentheymet ::= nothing | " when they met"

riverwalking ::= "walking beside the river"
rainsheltering ::= "as they both tried to escape the rain" | "as they both took shelter from the rain" | "when at a bus stop on a wet day, he said 'please share my umbrella'"
walkinghome ::= "walking home"




activity ::= activity##theplace
activity_riverwalk ::= "Skipping stones, they " | "As they walked, they "
activity_riverwalking ::= activity_riverwalk
activity_forestwalk ::= "As they walked, they " | "They " enjoyedthemselves " climbing trees. They " | "They sat down in a clearing and "
activity_picnic ::= "Lying on the grass, they enjoyed the " theseason " weather and " | "As they ate, they "
activity_watchsunset ::= "Sitting side by side on the grass, they " | "As the sky filled with colour, they "
activity_fairground ::= "They " enjoyedthemselves space funadverb " on the rides. Finally, sitting in the big wheel, they " | "After many energetic rides, they sat down to enjoy some ice creams and "
activity_themepark ::= "They " enjoyedthemselves space funadverb " on the rides. Sitting down to rest, they " | "The attractions were lots of fun. Eventually, they sat down and "
activity_watchfireworks ::= "They stood close as the colours and sounds filled the sky. " laterthey
activity_playground ::= "They " enjoyedthemselves space funadverb " on the " playgroundequipment ". Sitting " playgroundsittingplace ", they " | "She shrieked as they span the roundabout. Then they sat " playgroundsittingplace " and "
playgroundequipment ::= "slides" | "climbing frame" | "swings" | "see-saw" | playgroundequipment " and " playgroundequipment
playgroundsittingplace ::= "on the swings" | "on the bench" | "in the climbing frame"
activity_cinema ::= "At one point during the film, she grabbed hold of his arm. He " didntmind ". " laterthey | "During the film, he awkwardly slipped an arm around her shoulders. She " didntmind ". " laterthey
activity_cafe ::= "Over " cafeorder ", they " conversation "They "
cafeorder ::= "coffee" | "cakes" | "lunch" | "cream cakes"
activity_restaurant ::= "They " enjoyedthemselves " over sparkling wine and " | "Their eyes met as they "
activity_pool ::= "They " enjoyedthemselves space swimmingverb " and chasing one another. " laterthey | "After swimming some lengths and taking time to splash each other, they " | "They " enjoyedthemselves " taking turns on the waterslides. " laterthey
activity_beach ::= activity_beach##theseason
activity_beach_spring ::= "They watched the tide roll in and " | "They paddled, laughing at the icy water. " laterthey | "They sat on the sand and enjoyed the " theseason " sea breeze as they "
activity_beach_summer ::= "They " enjoyedthemselves space swimmingverb " in the sea. " laterthey | "The sand was warm as they sunbathed and " | activity_beach_spring
activity_beach_autumn ::= activity_beach_spring
activity_beach_winter ::= activity_beach_spring
swimmingverb ::= "splashing" | "swimming" | "splashing around"
activity_rainsheltering ::= "Hiding in a bus shelter, they got talking and " | "Waiting for the sudden shower to stop, they "
activity_walkinghome ::= "As they walked, they " | "The time passed quickly, as they "

enjoyedthemselves ::= "enjoyed themselves" | "had fun"
funadverb ::= "energetically" | "playfully" | "nostalgically"
didntmind ::= "didn't complain" | "gulped, but didn't say anything" | "just smiled " smileadverb
laterthey ::= "Afterwards, they " | "Later, they "




conversation ::= conversationverbphrase conversationtopic

conversationverbphrase ::= conversationadverb space conversationverb | conversationverb space conversationadverb | conversationverb | "had " conversationarticleandadjective space conversationnoun
conversationarticleandadjective ::= "an animated" | "a relaxed" | "a happy" | "a hesitant" | "a guarded" | "an enthusiastic" | "an idle"
conversationadverb ::= "animatedly" | "relaxedly" | "happily" | "hesitantly" | "guardedly" | "enthusiastically" | "idly"
conversationverb ::= "talked" | "chatted" | "talked" | "chatted" | "bantered"
conversationnoun ::= "conversation" | "chat" | "discussion" | "talk"
conversationtopic ::= " about what they want to do in the future. " | " and found out more about each other. " | " about the things they do for fun. " | " about the things they used to do as children. " | " about things they regretted from the past. " | " about their families. " | " and discovered shared interests. "




conclusion ::= "As the " thetime " drew to a close, " conclusionpossibility | "After " heorshe1 " walked " himorher2 " home, " conclusionpossibility
conclusionpossibility ::= alladream | displayofaffection | admitfeelings | dontadmitfeelings | friendlygoodbye | stalker
displayofaffection ::= heorshe1 space actionadverb " hugged " himorher2 space thensaidgoodbye | heorshe1 space actionadverb " took " hisorher2 " hand " thensaidgoodbye | heorshe1 space actionadverb " gave " himorher2 " a kiss " thensaidgoodbye
admitfeelings ::= "they " confessionadverb space confessionverb " their feelings to one another." | heorshe1 space confessionadverb space confessionverb space hisorher1 " feelings to " himorher2 "."
dontadmitfeelings ::= heorshe1 " looked like " heorshe1 " was wanting to say something, but ended up just telling " himorher2 ", See you soon!"
friendlygoodbye ::= "they smiled " adverb " and said " goodbye##thetime "." | "they each went to their own home with " smileadjective " smiles on their faces."
stalker ::= heorshe1 " was unaware that " hisorher1 " life was about to change drastically, as " hisorher2 " obsession would send both of them into a spiral of destruction."
alladream ::= heorshe1 " looked into " hisorher2 " eyes and reached up to touch " hisorher2 " cheek. As their lips met " heorshe1 " sighed blissfully. And then the alarm clock went off."

confessionadverb ::= "relaxedly" | "happily" | "hesitantly" | "guardedly" | "openly" | "accidentally" | "unintentionally"
confessionverb ::= "admitted" | "confessed" | "declared" | "hinted at"
actionadverb ::= "impulsively" | "nervously" | "intensely" | "gently"
adverb ::= conversationadverb | actionadverb
smileadjective ::= "secret" | "happy" | "intrigued" | "embarrassed" | "contented" | "sparkling"
smileadverb ::= "secretly" | "happily" | "intriguedly" | "embarrassedly" | "contentedly" | "sparklingly"
thensaidgoodbye ::= "then said " goodbye##thetime "."
goodbye_afternoon ::= "goodbye"
goodbye_evening ::= "goodnight"

chooseorder ::= <g1::=male> <g2::=female> | <g1::=female> <g2::=male>
heorshe1 ::= heorshe##g1
heorshe2 ::= heorshe##g2
HeorShe1? ::= HeorShe?##g1
hisorher1 ::= hisorher##g1
hisorher2 ::= hisorher##g2
himorher1 ::= himorher##g1
himorher2 ::= himorher##g2
heorshe_male ::= he
heorshe_female ::= she
himorher_male ::= him
himorher_female ::= her
hisorher_male ::= his
hisorher_female ::= her
[HeorShe male]? ::= He
[HeorShe female]? ::= She



CategoryGenerator

ec2-35-170-81-210.compute-1.amazonaws.com | ToothyWiki | AlexChurchill | RecentChanges | Login | Advent calendar | Webcomic
Edit this page | View other revisions | Recently used referrers
Last edited June 29, 2006 4:43 pm (viewing revision 7, which is the newest) (diff)
Search: